| /trunk/libraries/adc/min_env/env_target.py |
|---|
| 0,0 → 1,27 |
| # Create and initialize the environment. |
| env_target = Environment() |
| # Set environment for AVR-GCC. |
| env_target['CC'] = 'avr-gcc' |
| env_target['CPPPATH'] = '/usr/lib/avr/include' |
| env_target['OBJCOPY'] = 'avr-objcopy' |
| env_target['SIZE'] = 'avr-size' |
| env_target['AR'] = 'avr-ar' |
| env_target['RANLIB'] = 'avr-ranlib' |
| env_target.Append(CCFLAGS = '-Os') |
| # Define environment name. |
| env_target.Append(NAME = 'env_target') |
| # Microcontroller type. |
| env_target.Append(MCU = 'atmega328p') |
| # Microcontroller frequency in Hertz. |
| env_target.Append(F_CPU = '16000000UL') |
| # Set environment for an Atmel AVR ATmega328p microcontroller. |
| env_target.Append(CCFLAGS = '-mmcu=' + env_target['MCU']) |
| env_target.Append(LINKFLAGS = '-mmcu=' + env_target['MCU']) |
| env_target.Append(CPPDEFINES = 'F_CPU=' + env_target['F_CPU']) |
| # Export environment set for target. |
| Export('env_target') |
| /trunk/libraries/adc/min_env/build_tools.py |
|---|
| 0,0 → 1,41 |
| """ |
| Build project. |
| """ |
| def BuildProject(env, sources, target_name): |
| # Build program. |
| env.Program(target = target_name + '.elf', source = sources) |
| # Create hex binary file. |
| env.Command( |
| target_name + '.hex', |
| target_name + '.elf', |
| env['OBJCOPY'] + ' -O ihex $SOURCE $TARGET' |
| ) |
| AddMethod(Environment, BuildProject) |
| """ |
| Build library. |
| """ |
| def BuildLibrary(env, sources, target_name): |
| # Build static library. |
| env.StaticLibrary(target = target_name, source = sources) |
| # Append LIBPATH and LIBS. |
| env.Append(LIBPATH = [ '#build/libraries/' + target_name + '/' + env['NAME'] ]) |
| env.Append(LIBS = [ target_name ]) |
| AddMethod(Environment, BuildLibrary) |
| """ |
| Compute memory usage. |
| """ |
| def ComputeMemoryUsage(env, target_name): |
| # Compute memory usage. |
| env.Command( |
| None, |
| target_name + '.elf', |
| env['SIZE'] + ' -C --mcu=' + env['MCU'] + ' $SOURCE' |
| ) |
| AddMethod(Environment, ComputeMemoryUsage) |